;Citac, spolupracujici s programem pana Davida Matouska z KE2/2003
;Mereni se spousti ridicim bytem podle teto tabulky:
;
; Doba mereni  Preddelicka   Ridici byt
;    0,1 s         256           00
;     1  s         256           01
;     10 s         256           02
;    0,1 s          1            04
;     1  s          1            05
;     10 s          1            06
;
;ATmega8 odpovi stejnym bytem. Pokud doslo k preteceni, je nastaven nejvyssi bit
;Po ridicim bytu nasleduji 2 byty se zmerenou hodnotou
;Preddelicku je treba emulovat SW, takze nelze dosahnout f vetsi nez polovina
;systemovych hodin (tj. cca 3,5MHz). To je dano hardwarem ATmega8

.include "m8def.inc"
.def        Zero      =  r0          ;Always 0 !!!
.def        Cnt1      =  r1
.def        Cnt2      =  r2
.def        temp0     = r16
.def        temp1     = r17
.def        temp2     = r18
.def        temp3     = r19
.def        Cnt_9_s   = r20
.def        Ctrl_byt  = r21
.def    flags   =r28
;Flags:
.equ    Last     = 0    ;Pro urceni, pri kterem preruseni se ma ukoncit nacitani
.equ    Finish   = 1    ;Interval uplynul
.equ    Presc256 = 2
.equ    Overflow = 3
;******** Crystal ****************************************************
.equ fCK   = 7372800            ; X-tal frequency, Hz                *
.equ Baud  = 9600               ; Data rate, bauds                   *
.equ Tr_Sp = 0                  ; Transmission speed (U2X)           *
.equ UBR   = -1+(5+10*fCK/(16*Baud-8*Baud*Tr_Sp))/10 ;               *
;                                                                    *
.equ presc_1 = 1024                                  ;               *
.equ Set_0_1s = ((fCK/presc_1)/10)    ;0,1s  = 1/10  Hz              *
.equ Set_1s   = ((fCK/presc_1)/1)     ;1s    = 1/1   Hz              *
.equ Set_5s   = ((fCK/presc_1)/0.2)   ;5s    = 1/0.2 Hz              *
;*********************************************************************

;###########################################################################
.CSEG
;***************************************************************************
;*
;* Interrupt Vectors
;*
;***************************************************************************
        rjmp    INIT        ; Reset Handle
    	reti	            ; External Interrupt Request 0
        reti	            ; External Interrupt Request 1
        reti                ; Timer/Counter2 Compare Match
        reti	            ; Timer/Counter2 Overflow
        reti	            ; Timer/Counter1 Capture Event
        rjmp	Interval    ; Timer/Counter1 Compare Match A (Timer for measurement interval)
        reti	            ; Timer/Counter1 Compare Match B
        reti                ; Timer/Counter1 Overflow
        rjmp    Count       ; Timer/Counter0 Overflow        (External Event Count)
        reti	            ; Serial Transfer Complete
        reti                ; USART, Rx Complete
        reti                ; USART Data Register Empty
        reti	            ; USART, Tx Complete
        reti                ; ADC Conversion Complete
        reti	            ; EEPROM Ready
        reti	            ; Analog Comparator
        reti	            ; 2-wire Serial Interface
        reti	            ; Store Program Memory Ready

;***************************************************************************
INIT:
        ldi     temp1, low(RAMEND)          ; SP = RAMEND
        ldi     temp2, high(RAMEND)
        out     SPL, temp1
        out     SPH, temp2
;********************************
.if Tr_Sp                 ;     *
        sbi     UCSRA,U2x ;     *        
.else                     ;     *
        cbi     UCSRA,U2x ;     *
.endif                    ;     *
;********************************
        ldi     temp1, LOW(UBR)        
        out     UBRRL, temp1
.if HIGH(UBR)
        ldi     temp1, HIGH(UBR)        
        out     UBRRH, temp1
.endif
        ldi     temp1,(1<<RXEN)|(1<<TXEN)     ; Enable receiver & transmitter, 8-bit mode
        out     UCSRB,temp1                                        
        ldi     temp1,(1<<OCIE1A)|(1<<TOIE0)  ;Interrupt enable
        out     TIMSK,temp1
        clr     Zero
        out     TCCR1A,Zero          ;OC1A, OC1B disconnected
        out     TCCR1B,Zero          ;STOP timer 1
        out     TCCR0,Zero           ;STOP timer 0
        sei

Loop:
        rcall   getc                    ;Ctrl_byt
        clr     flags
        cpi     Ctrl_byt,3
        brsh    Measurement
        sbr     flags,(1<<Presc256)
Measurement:
        sbrs    Ctrl_byt,1              ;Je-li bit 1 nastaven, je interval 2*5s
        sbr     flags,(1<<Last)         ;Kdyz neni nastaven, je to posledni interval !
        clr     Cnt1
        clr     Cnt2
        out     TCNT0,Zero
        out     TCNT1H,Zero
        out     TCNT1L,Zero
        ldi     ZL,low(Table*2)         ; low
        ldi     ZH,high(Table*2)        ; high
        mov     temp1,Ctrl_byt
        lsl     temp1                   ;Multiplication 2 (table by twos)
        add     ZL,temp1
        adc     ZH,Zero
        lpm     temp1,Z+
        lpm     temp2,Z+
        out     OCR1AH,temp2
        out     OCR1AL,temp1
        ldi     temp1,(1<<CS02)|(1<<CS01)|(1<<CS00) ;External input
        ldi     temp2,(1<<WGM12)|(1<<CS12)|(1<<CS10);CTC, Prescaler 1024, START Timer 1
        out     TCCR1B,temp2                        ;Start measurement interval
        out     TCCR0,temp1                         ;Start External Event Counter
Counting:
        sbrs    flags,Finish            ;Probiha jeste pocitani ?
        rjmp    Counting                ;Ano, jeste cekat
        sbrc    flags,Last              ;Je to posledni interval ?
        rjmp    Answer                  ;Ano - odeslat vysledek
        sbr     flags,(1<<Last)         ;Ted uz to bude urcite posledni interval
        cbr     flags,(1<<Finish)       ;Vynulovat priznak ukonceni intervalu
        rjmp    Counting                ;Zpet na testovani konce druheho intervalu
Answer:
        sbrc     flags,Presc256         ;Je to mereni s preddelicem 256 ?
        rjmp    Common                  ;Ano, je mozno rovnou odeslat vysledek
;Prescaler 1
        mov     Cnt2,Cnt1               ;Neni, takze je treba posunout vysledek o 1 byt vyse
        in      Cnt1,TCNT0              ;dtto
Common:
        sbrc    flags,Overflow          ;Preteceni ?
        sbr     Ctrl_byt,(1<<7)         ;Ano, nastavit bit 7
Answ2:
        mov     temp1,Ctrl_byt
        rcall   putc
        mov     temp1,Cnt1
        rcall   putc
        mov     temp1,Cnt2
        rcall   putc
        rjmp    Loop

Table:        
.dw     Set_0_1s
.dw     Set_1s
.dw     Set_5s
.dw     0
.dw     Set_0_1s
.dw     Set_1s
.dw     Set_5s

                                        
putc:
        sbis     USR,UDRE        ; test for TX register empty
        rjmp     putc            ; loop until TX empty
        out      UDR,temp1       ; send the byte
        ret
getc:
        sbis     USR,RXC         ; wait until a character has been received
        rjmp     getc
        in       Ctrl_byt,UDR    ; Read byte from the UART
        ret

Interval:
        sbrs    flags,Last
        rjmp    Interval_End
        out     TCCR0,Zero        ;Stop Timer 0
        out     TCCR1B,Zero       ;Stop Timer 1
Interval_End:
        sbr     flags,(1<<Finish)
        reti
Count:
        inc     Cnt1
        brne    reti_
        sbrc    flags,Presc256
        rjmp    Pr256
        sbr     flags,(1<<Overflow)   ;Kdyz to doslo sem, jedna se o preteceni
        reti                          ;v rezimu bez preddelicky
Pr256:
        inc     Cnt2
        brne    reti_
        sbr     flags,(1<<Overflow)   ;Kdyz to doslo sem, jedna se o preteceni
reti_:                                ;v rezimu s preddelickou 
        reti